
栞 menu_setup

//バックログ宣言
スクリプト /Plugins/SRS_standard/backlog.txt

ダイアログスクリプト登録 /Plugins/SRS_standard/msg.txt

スクリプト /Plugins/SRS_standard/events.txt register

キーダウン r.click スクリプト /Plugins/SRS_standard/menu.txt menu_show

スクリプト終了

~//---------------------------------------------------------------

//メニュー
栞 menu_show

画面領域開始 my_menu

// 演出が通常時間で作動するように。
文字進行通常強制 true

// 作品中の全ての演出を一時停止させる。(背景音楽は除外)
//「全画面領域」の理由：メニューの下画面の個体に反映するため。
一時停止 "(?!vn_sysBGM).*" 全画面領域

スクリプト /Plugins/SRS_standard/textbox.txt txt_hide //現在表示中の文字窓を全て隠す

//注：名前の先に[]を付けると、セーブスクリーンショットに保存されません。
絵0 sysmenu /Plugins/SRS_standard/standard_menu/stm_bg.png 0 0 102 カメラ付着
.イン sysmenu 300


//メニューイメージとバトンを設定
//注：ボタン宣言後エディターのプレビュー画面の上で
//ボタンに触れるとタッチイメージに変わります。
//（ボタン位置調整時、これを利用すれば調整が
// もっと楽に出来ます）

//注：ボタンのレイヤーがメニューイメージのレイヤ
//より高いように設定

保存変数 メニュー表示中 = 1

タッチ素材設定 /Plugins/SRS_standard/standard_menu/st_menu_backlog.png /Plugins/SRS_standard/standard_menu/st_menu_backlog_white.png /Plugins/SRS_standard/standard_menu/st_menu_backlog_white.png /Plugins/SRS_standard/SFX/se_maoudamashii_system13.ogg /Plugins/SRS_standard/SFX/se_maoudamashii_system29.ogg
ボタン0 sysmenu_button1 60 245 104 カメラ付着 スクリプト /Plugins/SRS_standard/backlog.txt log_display
拡大  sysmenu_button1 90%
拡大  sysmenu_button1 100% 100
.イン sysmenu_button1 40

タッチ素材設定 /Plugins/SRS_standard/standard_menu/st_menu_save.png /Plugins/SRS_standard/standard_menu/st_menu_save_white.png /Plugins/SRS_standard/standard_menu/st_menu_save_white.png /Plugins/SRS_standard/SFX/se_maoudamashii_system13.ogg /Plugins/SRS_standard/SFX/se_maoudamashii_system29.ogg
ボタン0 sysmenu_button2 464 245 104 カメラ付着 スクリプト /Plugins/SRS_standard/save.txt display
拡大  sysmenu_button2 90%
拡大  sysmenu_button2 100% 100
.イン sysmenu_button2 40

タッチ素材設定 /Plugins/SRS_standard/standard_menu/st_menu_load.png /Plugins/SRS_standard/standard_menu/st_menu_load_white.png /Plugins/SRS_standard/standard_menu/st_menu_load_white.png /Plugins/SRS_standard/SFX/se_maoudamashii_system13.ogg /Plugins/SRS_standard/SFX/se_maoudamashii_system29.ogg
ボタン0 sysmenu_button3 464 335 104 カメラ付着 スクリプト /Plugins/SRS_standard/load.txt display
拡大  sysmenu_button3 90%
拡大  sysmenu_button3 100% 100
.イン sysmenu_button3 40

タッチ素材設定 /Plugins/SRS_standard/standard_menu/st_menu_config.png /Plugins/SRS_standard/standard_menu/st_menu_config_white.png /Plugins/SRS_standard/standard_menu/st_menu_config_white.png /Plugins/SRS_standard/SFX/se_maoudamashii_system13.ogg /Plugins/SRS_standard/SFX/se_maoudamashii_system29.ogg
ボタン0 sysmenu_button4 60 335 104 カメラ付着 スクリプト /Plugins/SRS_standard/config-system.txt config_in_first
拡大  sysmenu_button4 90%
拡大  sysmenu_button4 100% 100
.イン sysmenu_button4 40

タッチ素材設定 /Plugins/SRS_standard/standard_menu/st_menu_title.png /Plugins/SRS_standard/standard_menu/st_menu_title_white.png /Plugins/SRS_standard/standard_menu/st_menu_title_white.png /Plugins/SRS_standard/SFX/se_maoudamashii_system13.ogg /Plugins/SRS_standard/SFX/se_maoudamashii_system29.ogg
ボタン0 sysmenu_button5 868 245 104 カメラ付着 ダイアログ "タイトルへ戻りますか？" ジャンプ to_title
拡大  sysmenu_button5 90%
拡大  sysmenu_button5 100% 100
.イン sysmenu_button5 40

タッチ素材設定 /Plugins/SRS_standard/standard_menu/st_menu_return.png /Plugins/SRS_standard/standard_menu/st_menu_return_white.png /Plugins/SRS_standard/standard_menu/st_menu_return_white.png /Plugins/SRS_standard/SFX/se_maoudamashii_system13.ogg /Plugins/SRS_standard/SFX/se_maoudamashii_system29.ogg
ボタン0 sysmenu_button6 868 335 104 カメラ付着 ジャンプ menu_out
.イン sysmenu_button6 80

栞 menu_reappear

文字進行通常強制 true
キーダウン r.click ジャンプ menu_out

// ここから先はボタンによる操作のみ可能にするように。
待機 続行禁止

~//---------------------------------------------------------------

//メニュー関連リソース全部解除
栞 menu_out

// 演出中にボタン等が反応しないように
入力禁止 true

スクリプト /Plugins/SRS_standard/textbox.txt txt_show //文字窓を全て表示

// この画面領域の個体を全部消去
.アウト 全部 300

文字進行通常強制 false

栞 menu_out_end

保存変数 メニュー表示中 = 0

// 作品中の全ての演出を再開させる
再生続行 "(?!vn_sysBGM).*" 全画面領域

入力禁止 false

画面領域終了 my_menu

スクリプト終了

~//---------------------------------------------------------------
栞 to_title

// 演出中にボタン等が反応しないように
入力禁止 true

//「全画面領域」の理由：メニューの下画面の個体まで全部消すため。
.アウト 全部 800 全画面領域

入力禁止 false

最終ジャンプ title.txt

スクリプト終了

~//---------------------------------------------------------------
栞 text_skip

スクリプト終了

//注意：スクリプトの最後に１行以上の空き空間を残してください。





