
栞 log_init

// バックログを含めた、「バックログ設定」により
// 作られるボイス再生ボタンなどが
// 全部バックログ画面に所属されるように。
画面領域開始 my_backlog

//バックログ設定
//注：バックログのレイヤーは使用する文字窓のレイヤーの数値に
//設定されます。
//バックログ特性上大抵のリソースより前に出る必要がある点を
//考慮し比較的高い数値に設定してください（ここでは201）

// バックログの文字表示領域と文字特性を設定。
文字窓 backlog_textbox 140 152 301 960 510 /Plugins/SRS_standard/Fonts/KozMinPro-Light_0.otf 20 カメラ付着
使用文字窓 backlog_textbox 
文字色 0 0 0 // 255 255 255
文字陰 0
文字色 #ffffff
文字ワードラップ false

// バックログボイスボタンの素材を設定。
タッチ素材設定 /Plugins/SRS_standard/standard_backlog/voice_icon.png /Plugins/SRS_standard/standard_backlog/voice_icon_white.png /Plugins/SRS_standard/standard_backlog/voice_icon_white.png /Plugins/SRS_standard/SFX/se_maoudamashii_system48.ogg /Plugins/SRS_standard/SFX/se_maoudamashii_system47.ogg

// バックログを宣言、詳細設定を調整。
バックログ設定 backlog_textbox 
バックログ台詞登録 true
バックログ改ページ接頭辞 "\n\n"
バックログボイス位置 -10 0

画面領域終了 my_backlog

//ウィールアップ時バックログ召還
//（現在スクリプトの「log_display」ブックマークから読み込むように設定）
キーダウン wheel.up スクリプト /Plugins/SRS_standard/backlog.txt log_display

スクリプト終了

//クリア色 100 100 100
~//---------------------------------------------------------------
栞 log_display

画面領域開始 my_backlog

// 演出が通常時間で作動するように。
文字進行通常強制 true

//注：メニューを含む全てのリソースより上にバックログイメージが
//表示されるようレイヤーを高い数字にする

~絵 backlog_main_bg /Plugins/SRS_standard/standard_backlog/st_backlog_bg.png 0 0 250 カメラ付着

タッチ素材設定 /Plugins/SRS_standard/standard_config/stc_x.png /Plugins/SRS_standard/standard_config/stc_x_white.png /Plugins/SRS_standard/standard_config/stc_x_white.png /Plugins/SRS_standard/SFX/se_maoudamashii_system13.ogg /Plugins/SRS_standard/SFX/se_maoudamashii_system46.ogg
ボタン0 backlog_main_btn_close 1160 23 280 カメラ付着 ジャンプ log_out

.イン backlog_main.* 300
//バックログ機能開始
イン バックログ

~絵0 backlog_main_scroll /Plugins/SRS_standard/standard_backlog/stbl_bar.png 1187 153 300 カメラ付着
タッチ素材設定 /Plugins/SRS_standard/standard_config/stc_boll.png /Plugins/SRS_standard/standard_config/stc_boll_white.png /Plugins/SRS_standard/standard_config/stc_boll_white.png /Plugins/SRS_standard/SFX/se_maoudamashii_system47.ogg
~トラックバー0 backlog_main_scrollball 1207 172 301 縦 473 vn_backlog_pos 0 100 カメラ付着

.イン backlog_textbox, backlog_main_scroll.* 300

//バックログ解除方法:
//1. 右クリック
//2. 「close」ボタンクリック 
//3. バックログを最後までスクロール (自動的に全ての待機状態解除)
キーダウン r.click ジャンプ log_out

キーダウン wheel.up バックログスクロール -1
キーダウン wheel.down バックログスクロール 1

//クリックやEnterによる一般的なスクリプト読み込み続行を禁止
//ジャンプによってのみこの行を乗り越え、読み込みを再開する事が可能。
待機 続行禁止

~//---------------------------------------------------------------
栞 log_out

// バックログと関連リソースを解除
// バックログは消えてほしくないため、透明度で調整。
透明度 backlog_textbox 0 300
.アウト backlog_main.* 300
アウト バックログ
//.アウト backlog_bg, backlog_btn_close 200
//アウト backlog_.* 200

ボタン活性スタック pop

//キートリガー設定
//ウィールアップ：バックログ再び召還
//右クリック：メニュー召還
キーダウン wheel.up スクリプト /Plugins/SRS_standard/backlog.txt log_display
キーダウン r.click スクリプト /Plugins/SRS_standard/menu.txt menu_show
スクリプト /Plugins/SRS_standard/textbox.txt txt_setToggles

文字進行通常強制 false

画面領域終了 my_backlog
スクリプト終了



